Patient and Resultative

The case 'patient' is selected for the subject, if the main verb is passive, and removed if the main verb is a transitive verb with an object.¹⁴ A special rule handles OVS, not by looking for an object, but by removing 'patiens' if you are certain that the element is subject of a transitive verb; this rule is written to handle direct speech,'``Who is it?'', he said' which is OVS in Danish, and is only triggered with speech-verbs. Another rule removes the patiens-reading from subjects even if the object is not expressed, but is a suppressed object pronouns in a relative clause, e.g. `The woman, (that) the wolf ate, was old'. The last group of rules unconditionally removes the patiens reading from subjects of intransitive verbs; no conditions on this rule have been necessary yet, but will be added as the grammar grows, depending on the semantics of the verb.

The patient-selection rules has been copied for resultative, with an extra condition that the main verb has to belong to a special small class of verbs (V-RES: build, make etc.). No copying of remove-tags has been made. Instead removal is handled in clean-up, where a rule removes all resultative tags, that are not the only possible analysis. This may turn out to be too crude a solution.

#############
# SELECT %PAT

SELECT (%PAT) (0 @SUBJ>) (*1 @MV BARRIER CLB/SB LINK 0 PAS) ; 
                              # ulven blev fanget, ulven fangedes
SELECT (%PAT) (0 @<SUBJ) (*-1 @MV BARRIER CLB/SB LINK 0 PAS) ; 
                              # derfor fangedes ulven
SELECT (%PAT) (0 @<SUBJ) (*1 @MV BARRIER CLB/SB LINK 0 PCP2 LINK 0
        %PAS) ;               # derfor blev ulven fanget
SELECT (%PAT) (0 @SUBJ>) (*1 CLB BARRIER @MV LINK *1 VFIN LINK 
       0 @FS-N< LINK *1 VFIN BARRIER @SUBJ> LINK -1 ALL LINK *1 @MV 
       LINK 0 PAS) ; # ulven, som ..., blev fanget; ulven, som ..., 
       fangedes; kan ikke klare 'ulven, som ..., fordi ..., fangedes'

#############
# REMOVE %PAT

REMOVE (%PAT) (0 @SUBJ>) (*1 @MV BARRIER CLB/SB LINK 0 <vt> LINK 
       *1C @<ACC& BARRIER @MV) ; # ulven spiste kaninen
REMOVE (%PAT) (0 @<SUBJ) (*-1 @MV BARRIER CLB/SB LINK 0 <vt> LINK 
       *1C @<ACC& BARRIER @MV) ; # derfor spiste ulven kaninen
REMOVE (%PAT) (0 @<SUBJ) (*1 @MV BARRIER CLB/SB LINK 0 <vt> LINK 
       0  @ICL-AUX< LINK *1C @<ACC& BARRIER @MV) ; 
                                 # Derfor har ulven spist kaninen
REMOVE (%PAT) (0 @<SUBJ) (*-1 @MV BARRIER CLB/SB LINK 0 <vt> LINK 
       NOT 0 <vi>) ;             # "Hvem er det?" spurgte hun. : 

REMOVE (%PAT) (0 @SUBJ>) (*1 @SUBJ> BARRIER VFIN LINK *1 VFIN LINK 
       *1 VFIN BARRIER @SUBJ> LINK NOT -1 KC LINK *2C @<ACC 
       BARRIER VFIN); # Ulven, der blev fanget, havde spist kaninen
REMOVE (%PAT) (0 @<SUBJ) (*-1 @MV BARRIER CLB/SB LINK 0 (<vt>) LINK 
       *1C @MV LINK *1C CLB LINK *1 @<ACC& BARRIER @MV) ; 
       # Derfor spiste ulven, der kun havde fanget det ene dyr, kaninen

REMOVE (%PAT) (0 @SUBJ>) (*1 @MV BARRIER CLB/SB LINK 0 (<vt>) LINK 
       1 ALL LINK *-1 VFIN BARRIER NON-V LINK 0 @FS-N<); 
       # vt i bis. uden obj. "..., hun havde sparket, ...

REMOVE (%PAT) (0 @SUBJ>) (*1 @MV BARRIER CLB/SB LINK 0 <vi>); #Manden gik
REMOVE (%PAT) (0 @<SUBJ) (*-1 @MV BARRIER CLB/SB LINK 0 <vi>); 
                                   #derfor gik manden
REMOVE (%PAT) (0 @<SUBJ) (*1 @MV BARRIER CLB/SB LINK 0 <vi> LINK 
       0 @ICL-AUX<);               #derfor er manden gået
REMOVE (%PAT) (0 @SUBJ>) (*1 CLB BARRIER VFIN LINK *1 VFIN LINK 0 
       @FS-N< LINK *1 VFIN BARRIER @SUBJ LINK -1 ALL LINK *1 @MV 
       LINK 0 <vi>);               #Manden, som ..., gik